*

*Continuous conditioning circuit with a variable capacitor

***** Parameter definition*******
* gap closing transducer parameters: initial gap, area
.params d0=45e-6
.params S=1e-4

* Mobile electrode sinusoidal motion parameters: amplitude, freq. in Hz
.params X0=42e-6
.params f=100

* Permittivity of the vacuum
.params eps0=8.85e-12

* Parasitic capacitance in series with the transducer
.params Cp=30e-12

*Load resistance
.params RL=1

* Bias voltage
.params Vbias=40
****************************************


********* The netlist:

* Definition of the variable capacitance
Vdisp disp 0 sine ( 0 {X0} {f*2*3.14} 0 0 0 0)
Ecvar Cvar 0 value={eps0*S/(d0-V(disp))}

* Current generated by the variable capacitor
Bi_Cvar C1 0 I=(V(Cvar)*ddt(V(C1))+V(C1)*ddt(V(Cvar)))
*parasitic capacitance
Cp C1 0 {Cp}

* load resistance and bias voltage
Rl C1 bias {RL}
V0 bias 0 {Vbias}

******Simulator commands

* Transient simulation
.tran 0 1 0 1E-2

** step on three values of Rload
** .step param Rl list 1e6 10e6 30e6

** Measure the power on the load resistance
.measure tran LoadPower avg V(C1,bias)*V(C1,bias)/RL

** simulation parameters
.options method=gear reltol=1e-6
.end