1 | /******************************************************************************* |
---|
2 | * |
---|
3 | * Copyright (c) 1993 Intel Corporation |
---|
4 | * |
---|
5 | * Intel hereby grants you permission to copy, modify, and distribute this |
---|
6 | * software and its documentation. Intel grants this permission provided |
---|
7 | * that the above copyright notice appears in all copies and that both the |
---|
8 | * copyright notice and this permission notice appear in supporting |
---|
9 | * documentation. In addition, Intel grants this permission provided that |
---|
10 | * you prominently mark as "not part of the original" any modifications |
---|
11 | * made to this software or documentation, and that the name of Intel |
---|
12 | * Corporation not be used in advertising or publicity pertaining to |
---|
13 | * distribution of the software or the documentation without specific, |
---|
14 | * written prior permission. |
---|
15 | * |
---|
16 | * Intel Corporation provides this AS IS, WITHOUT ANY WARRANTY, EXPRESS OR |
---|
17 | * IMPLIED, INCLUDING, WITHOUT LIMITATION, ANY WARRANTY OF MERCHANTABILITY |
---|
18 | * OR FITNESS FOR A PARTICULAR PURPOSE. Intel makes no guarantee or |
---|
19 | * representations regarding the use of, or the results of the use of, |
---|
20 | * the software and documentation in terms of correctness, accuracy, |
---|
21 | * reliability, currentness, or otherwise; and you rely on the software, |
---|
22 | * documentation and results solely at your own risk. |
---|
23 | * |
---|
24 | * IN NO EVENT SHALL INTEL BE LIABLE FOR ANY LOSS OF USE, LOSS OF BUSINESS, |
---|
25 | * LOSS OF PROFITS, INDIRECT, INCIDENTAL, SPECIAL OR CONSEQUENTIAL DAMAGES |
---|
26 | * OF ANY KIND. IN NO EVENT SHALL INTEL'S TOTAL LIABILITY EXCEED THE SUM |
---|
27 | * PAID TO INTEL FOR THE PRODUCT LICENSED HEREUNDER. |
---|
28 | * |
---|
29 | ******************************************************************************/ |
---|
30 | |
---|
31 | .file "strch_ca.s" |
---|
32 | #ifdef __PIC |
---|
33 | .pic |
---|
34 | #endif |
---|
35 | #ifdef __PID |
---|
36 | .pid |
---|
37 | #endif |
---|
38 | /* |
---|
39 | * (c) copyright 1988,1993 Intel Corp., all rights reserved |
---|
40 | */ |
---|
41 | |
---|
42 | /* |
---|
43 | procedure strchr (optimized assembler version for the CA) |
---|
44 | |
---|
45 | src_addr = strchr (src_addr, char) |
---|
46 | |
---|
47 | return a pointer to the first byte that contains the indicated |
---|
48 | byte in the source string. Return null if the byte is not found. |
---|
49 | |
---|
50 | Undefined behavior will occur if the end of the source string (i.e. |
---|
51 | the terminating null byte) is in the last two words of the program's |
---|
52 | allocated memory space. This is so because, in several cases, strchr |
---|
53 | will fetch ahead. Disallowing the fetch ahead would impose a severe |
---|
54 | performance penalty. |
---|
55 | |
---|
56 | This program handles two cases: |
---|
57 | |
---|
58 | 1) the argument starts on a word boundary |
---|
59 | 2) the argument doesn't start on a word boundary |
---|
60 | |
---|
61 | At the time of this writing, only g0 thru g7 and g13 are available |
---|
62 | for use in this leafproc; other registers would have to be saved and |
---|
63 | restored. These nine registers, plus tricky use of g14 are sufficient |
---|
64 | to implement the routine. The registers are used as follows: |
---|
65 | |
---|
66 | g0 src ptr; upon return it is a pointer to the matching byte, or null |
---|
67 | g1 char to seek |
---|
68 | g2 mask to avoid unimportant bytes in first word |
---|
69 | g3 char to seek, broadcast to all four bytes |
---|
70 | g4 word of the source string |
---|
71 | g5 copy of the word |
---|
72 | g6 extracted character |
---|
73 | g7 byte extraction mask |
---|
74 | g13 return address |
---|
75 | g14 |
---|
76 | */ |
---|
77 | |
---|
78 | .globl _strchr |
---|
79 | .globl __strchr |
---|
80 | .leafproc _strchr, __strchr |
---|
81 | .align 2 |
---|
82 | _strchr: |
---|
83 | #ifndef __PIC |
---|
84 | lda Lrett,g14 |
---|
85 | #else |
---|
86 | lda Lrett-(.+8)(ip),g14 |
---|
87 | #endif |
---|
88 | __strchr: |
---|
89 | |
---|
90 | lda 0xff,g7 # byte extraction mask |
---|
91 | and g1,g7,g1 # make char an 8-bit ordinal |
---|
92 | shlo 8,g1,g2 # broadcast the char to four bytes |
---|
93 | or g1,g2,g2 |
---|
94 | shlo 16,g2,g4 |
---|
95 | cmpo g1,g7 # is char being sought 0xff? |
---|
96 | or g4,g2,g3 |
---|
97 | lda (g14),g13 # preserve return address |
---|
98 | notand g0,3,g5 # extract word addr of start of src |
---|
99 | lda 0,g14 # conform to register linkage standard |
---|
100 | and g0,3,g6 # extract byte offset of src |
---|
101 | ld (g5),g4 # fetch word containing at least first byte |
---|
102 | shlo 3,g6,g6 # get shift count for making mask for first word |
---|
103 | lda 4(g5),g0 # post-increment src word pointer |
---|
104 | subi 1,0,g5 # mask initially all ones |
---|
105 | #if __i960_BIG_ENDIAN__ |
---|
106 | shro g6,g5,g5 # get mask for bytes needed from first word |
---|
107 | #else |
---|
108 | shlo g6,g5,g5 # get mask for bytes needed from first word |
---|
109 | #endif |
---|
110 | notor g4,g5,g4 # set unneeded bytes to all ones |
---|
111 | be.f Lsearch_for_0xff # branch if seeking 0xff |
---|
112 | |
---|
113 | Lsearch_for_word_with_char_or_null: |
---|
114 | scanbyte g3,g4 # check for byte with char |
---|
115 | lda (g4),g5 # copy word |
---|
116 | ld (g0),g4 # fetch next word of src |
---|
117 | bo.f Lsearch_for_char # branch if null found |
---|
118 | scanbyte 0,g5 # check for null byte |
---|
119 | lda 4(g0),g0 # post-increment src word pointer |
---|
120 | bno.t Lsearch_for_word_with_char_or_null # branch if not null |
---|
121 | |
---|
122 | Lnot_found: |
---|
123 | mov 0,g0 # char not found. Return null |
---|
124 | Lexit_code: |
---|
125 | bx (g13) # g0 = addr of char in src (or null); g14 = 0 |
---|
126 | Lrett: |
---|
127 | ret |
---|
128 | |
---|
129 | Lsearch_for_char: |
---|
130 | subo 5,g0,g0 # back up the byte pointer |
---|
131 | Lsearch_for_char.a: |
---|
132 | #if __i960_BIG_ENDIAN__ |
---|
133 | rotate 8,g5,g5 # shift word to position next byte |
---|
134 | #endif |
---|
135 | and g5,g7,g6 # extract byte |
---|
136 | cmpo g1,g6 # is it char? |
---|
137 | lda 1(g0),g0 # bump src byte ptr |
---|
138 | #if ! __i960_BIG_ENDIAN__ |
---|
139 | shro 8,g5,g5 # shift word to position next byte |
---|
140 | #endif |
---|
141 | be.f Lexit_code |
---|
142 | cmpobne.t 0,g6,Lsearch_for_char.a # quit if null comes before char |
---|
143 | b Lnot_found |
---|
144 | |
---|
145 | Lsearch_for_0xff: |
---|
146 | lda 0xf0f0f0f0,g2 # make first comparison mask for char=-1 case. |
---|
147 | or g5,g2,g2 |
---|
148 | and g4,g2,g4 # make unimportant bytes of first word 0x0f |
---|
149 | b Lsearch_for_word_with_char_or_null |
---|
150 | |
---|
151 | /* end of strchr */ |
---|
152 | |
---|