source: soft/giet_vm/sys/switch.s @ 206

Last change on this file since 206 was 199, checked in by alain, 12 years ago

Introducing the "idle" to improve the exit mechanism.
File size: 4.9 KB
Line 
1/******************************************************************************
2* This function receives two arguments that are the current task context
3* physical addresses and the next task context physical address.
4* The DTLB is temporary desactivated...
5******************************************************************************/
6
7    .globl  _task_switch
8    .func   _task_switch
9    .type   _task_switch, %function
10
11_task_switch:
12
13    /* desactivate DTLB */
14    ori         $27,    $0,             0xB
15    mtc2        $27,    $1                      /* DTLB desactivated */
16
17    /* save _current task context */
18    add     $27,    $4,     $0  /* $27 <= &context[curr_task_id] */
19
20    .set noat
21    sw      $1,     1*4($27)    /* ctx[1] <= $1 */
22    .set at
23    sw      $2,     2*4($27)    /* ctx[2] <= $2 */
24    sw      $3,     3*4($27)    /* ctx[3] <= $3 */
25    sw      $4,     4*4($27)    /* ctx[4] <= $4 */
26    sw      $5,     5*4($27)    /* ctx[5] <= $5 */
27    sw      $6,     6*4($27)    /* ctx[6] <= $6 */
28    sw      $7,     7*4($27)    /* ctx[7] <= $7 */
29    sw      $8,     8*4($27)    /* ctx[8] <= $8 */
30    sw      $9,     9*4($27)    /* ctx[9] <= $9 */
31    sw      $10,    10*4($27)   /* ctx[10] <= $10 */
32    sw      $11,    11*4($27)   /* ctx[11] <= $11 */
33    sw      $12,    12*4($27)   /* ctx[12] <= $12 */
34    sw      $13,    13*4($27)   /* ctx[13] <= $13 */
35    sw      $14,    14*4($27)   /* ctx[14] <= $14 */
36    sw      $15,    15*4($27)   /* ctx[15] <= $15 */
37    sw      $16,    16*4($27)   /* ctx[16] <= $16 */
38    sw      $17,    17*4($27)   /* ctx[17] <= $17 */
39    sw      $18,    18*4($27)   /* ctx[18] <= $18 */
40    sw      $19,    19*4($27)   /* ctx[19] <= $19 */
41    sw      $20,    20*4($27)   /* ctx[20] <= $20 */
42    sw      $21,    21*4($27)   /* ctx[21] <= $21 */
43    sw      $22,    22*4($27)   /* ctx[22] <= $22 */
44    sw      $23,    23*4($27)   /* ctx[23] <= $23 */
45    sw      $24,    24*4($27)   /* ctx[24] <= $24 */
46    sw      $25,    25*4($27)   /* ctx[25] <= $25 */
47    mflo    $26
48    sw      $26,    26*4($27)   /* ctx[26] <= LO  */
49    mfhi    $26
50    sw      $26,    27*4($27)   /* ctx[27] <= H1  */
51    sw      $28,    28*4($27)   /* ctx[28] <= $28 */
52    sw      $29,    29*4($27)   /* ctx[29] <= $29 */
53    sw      $30,    30*4($27)   /* ctx[30] <= $30 */
54    sw      $31,    31*4($27)   /* ctx[31] <= $31 */
55    mfc0    $26,    $14
56    sw      $26,    32*4($27)   /* ctx[32] <= EPC */
57    mfc0    $26,    $13
58    sw      $26,    33*4($27)   /* ctx[33] <= CR  */
59    mfc0    $26,    $12
60    sw      $26,    34*4($27)   /* ctx[34] <= SR  */
61    mfc0    $26,    $8
62    sw      $26,    35*4($27)   /* ctx[34] <= BVAR */
63    mfc2    $26,    $0
64    sw      $26,    39*4($27)   /* ctx[35] <= PTPR */
65
66    /* restore next task context */
67    add     $27,    $5,     $0  /* $27<= &context[next_task_id] */
68
69    .set noat
70    lw      $1,     1*4($27)    /* restore $1 */
71    .set at
72    lw      $2,     2*4($27)    /* restore $2 */
73    lw      $3,     3*4($27)    /* restore $3 */
74    lw      $4,     4*4($27)    /* restore $4 */
75    lw      $5,     5*4($27)    /* restore $5 */
76    lw      $6,     6*4($27)    /* restore $6 */
77    lw      $7,     7*4($27)    /* restore $7 */
78    lw      $8,     8*4($27)    /* restore $8 */
79    lw      $9,     9*4($27)    /* restore $9 */
80    lw      $10,    10*4($27)   /* restore $10 */
81    lw      $11,    11*4($27)   /* restore $11 */
82    lw      $12,    12*4($27)   /* restore $12 */
83    lw      $13,    13*4($27)   /* restore $13 */
84    lw      $14,    14*4($27)   /* restore $14 */
85    lw      $15,    15*4($27)   /* restore $15 */
86    lw      $16,    16*4($27)   /* restore $16 */
87    lw      $17,    17*4($27)   /* restore $17 */
88    lw      $18,    18*4($27)   /* restore $18 */
89    lw      $19,    19*4($27)   /* restore $19 */
90    lw      $20,    20*4($27)   /* restore $20 */
91    lw      $21,    21*4($27)   /* restore $21 */
92    lw      $22,    22*4($27)   /* restore $22 */
93    lw      $23,    23*4($27)   /* restore $23 */
94    lw      $24,    24*4($27)   /* restore $24 */
95    lw      $25,    25*4($27)   /* restore $25 */
96    lw      $26,    26*4($27)
97    mtlo    $26                 /* restore LO */
98    lw      $26,    27*4($27)
99    mthi    $26                 /* restore HI */
100    lw      $28,    28*4($27)   /* restore $28 */
101    lw      $29,    29*4($27)   /* restore $29 */
102    lw      $30,    30*4($27)   /* restore $30 */
103    lw      $31,    31*4($27)   /* restore $31 */
104    lw      $26,    32*4($27)
105    mtc0    $26,    $14         /* restore EPC */
106    lw      $26,    33*4($27)
107    mtc0    $26,    $13         /* restore CR */
108    lw      $26,    34*4($27)
109    mtc0    $26,    $12         /* restore SR */
110    lw      $26,    35*4($27)
111    mtc0    $26,    $8          /* restore BVAR */
112    lw      $26,    39*4($27)
113    mtc2    $26,    $0          /* restore PTPR */
114
115    /* activate DTLB */
116    ori         $27,    $0,             0xF
117    mtc2        $27,    $1     
118
119    /* returns to caller */
120    jr      $31 
121
122    .endfunc
123    .size _task_switch, .-_task_switch
124
Note: See TracBrowser for help on using the repository browser.