Changeset 339 for trunk/hal/x86_64/core/hal_cpu.S

Timestamp:

Aug 7, 2017, 3:11:45 PM (7 years ago)

Author:

max@…

Message:

Add support for context switch - not tested yet, due to some other bugs in
the mapper. This cswitch is similar to that of TSAR.

File:

• trunk/hal/x86_64/core/hal_cpu.S (modified) (2 diffs)

trunk/hal/x86_64/core/hal_cpu.S

@@ -24 +24 @@
 #include <hal_segmentation.h>
 #include <hal_register.h>
+#include <hal_kentry.h>
 
 ASM_ENTRY(lgdt)
@@ -181 +182 @@
 /* -------------------------------------------------------------------------- */
 
+ASM_ENTRY(cpu_context_switch)
+        pushq   %r12
+        pushq   %r13
+
+        movq    %rdi,%r13       /* oldctx */
+        movq    %rsi,%r12       /* newctx */
+
+        /*
+         * Save the current stack in %rdx, and switch to the trap frame of
+         * the old thread.
+         */
+        movq    %rsp,%rdx
+        movq    CTX_TF(%r13),%rsp
+        addq    $TF_SIZE,%rsp   /* end of the structure */
+
+        /* Build the trap frame */
+        movl    %ss,%eax
+        pushq   %rax            /* tf_ss */
+        pushq   %rdx            /* tf_rsp */
+        pushfq                  /* tf_rflags */
+        movl    %cs,%eax
+        pushq   %rax            /* tf_cs */
+        movabsq $thr_resume,%rax
+        pushq   %rax            /* tf_rip */
+        pushq   $0              /* tf_err */
+        pushq   $T_ASTFLT       /* tf_trapno */
+        INTR_SAVE_REGS
+
+        /* Switch rsp0 */
+        movq    CTX_RSP0(%r12),%rax
+        movq    TLSVAR(RSP0),%rdx
+        movq    %rax,(%rdx)
+
+        /* Switch to the new trap frame */
+        movq    CTX_TF(%r12),%rsp
+
+        /*
+         * Restore the context, and jump into the new thread.
+         */
+        INTR_RESTORE_REGS
+        iretq
+
+thr_resume:
+        /*
+         * Only pop %r12 and %r13, and return.
+         */
+        popq    %r13
+        popq    %r12
+
+        ret
+
+/* -------------------------------------------------------------------------- */
+
 ASM_ENTRY(atomic_cas_32)
         movl    %esi,%eax